还原.

build.gradle

@@ -0,0 +1,249 @@
+import java.text.SimpleDateFormat
+
+buildscript {
+    repositories {
+        mavenCentral()
+        maven { url "https://plugins.gradle.org/m2/" }
+    }
+
+    dependencies {
+        //noinspection DifferentKotlinGradleVersion
+        classpath 'org.jetbrains.kotlin:kotlin-gradle-plugin:1.3.21'
+        classpath "gradle.plugin.com.hierynomus.gradle.plugins:license-gradle-plugin:0.15.0"
+    }
+}
+ext {
+    configuration = [
+        javaVersion = JavaVersion.VERSION_1_8
+    ]
+
+    libraries = [
+        mybatisSpringVersion = '2.0.1',
+        mybatisVersion = '3.5.1',
+        springVersion = '5.1.6.RELEASE',
+        jsqlparserVersion = '1.2',
+        junitVersion = '5.4.0',
+    ]
+
+    lib = [
+        "kotlin-reflect"        : "org.jetbrains.kotlin:kotlin-reflect:1.3.10",
+        "kotlin-stdlib-jdk8"    : "org.jetbrains.kotlin:kotlin-stdlib-jdk8:1.3.10",
+        "jsqlparser"            : "com.github.jsqlparser:jsqlparser:${jsqlparserVersion}",
+        "mybatis-spring"        : "org.mybatis:mybatis-spring:${mybatisSpringVersion}",
+        "mybatis"               : "org.mybatis:mybatis:${mybatisVersion}",
+        "spring-context-support": "org.springframework:spring-context-support:${springVersion}",
+        "spring-jdbc"           : "org.springframework:spring-jdbc:${springVersion}",
+        "spring-tx"             : "org.springframework:spring-tx:${springVersion}",
+        "spring-web"            : "org.springframework:spring-web:${springVersion}",
+        "spring-aop"            : "org.springframework:spring-aop:${springVersion}",
+        "cglib"                 : "cglib:cglib:3.2.6",
+        "lombok"                : "org.projectlombok:lombok:1.18.4",
+
+        "javax.servlet-api"     : "javax.servlet:javax.servlet-api:4.0.1",
+        "aspectjweaver"         : "org.aspectj:aspectjweaver:1.9.2",
+        "mockito"               : "org.mockito:mockito-core:2.24.0",
+        "mybatis-ehcache"       : "org.mybatis.caches:mybatis-ehcache:1.1.0",
+        "slf4j-api"             : "org.slf4j:slf4j-api:1.7.25",
+        "logback-classic"       : "ch.qos.logback:logback-classic:1.2.3",
+        //test
+        "spring-test"           : "org.springframework:spring-test:${springVersion}",
+        "assertj-core"          : "org.assertj:assertj-core:3.12.2",
+        "junit-jupiter-api"     : "org.junit.jupiter:junit-jupiter-api:${junitVersion}",
+        "junit-jupiter-engine"  : "org.junit.jupiter:junit-jupiter-engine:${junitVersion}",
+        "mockito-all"           : "org.mockito:mockito-all:1.10.19",
+        "fastjson"              : "com.alibaba:fastjson:1.2.56",
+        "jackson"               : "com.fasterxml.jackson.core:jackson-databind:2.9.6",
+        "tomcatjdbc"            : "org.apache.tomcat:tomcat-jdbc:9.0.16",
+        "lagarto"               : "org.jodd:jodd-lagarto:5.0.7",
+        //datasource
+        "hikaricp"              : "com.zaxxer:HikariCP:3.3.0",
+        "druid"                 : "com.alibaba:druid:1.0.29",
+        "p6spy"                 : "p6spy:p6spy:3.8.1",
+        "commons-dbcp2"         : "org.apache.commons:commons-dbcp2:2.5.0",
+        "sqlserver"             : "com.microsoft.sqlserver:sqljdbc4:4.0",
+        "postgresql"            : "org.postgresql:postgresql:9.4.1212",
+        "oracle"                : fileTree(dir: 'libs', includes: ['ojdbc-11.2.0.3-jdk16.jar']),
+        "h2"                    : "com.h2database:h2:1.4.197",
+        "mysql"                 : "mysql:mysql-connector-java:8.0.15",
+        //code generator
+        "velocity"              : "org.apache.velocity:velocity-engine-core:2.0",
+        "freemarker"            : "org.freemarker:freemarker:2.3.28",
+        "beetl"                 : "com.ibeetl:beetl:2.9.8",
+        "swagger-annotations"   : "io.swagger:swagger-annotations:1.5.21"
+    ]
+}
+
+allprojects {
+    group = 'com.baomidou'
+    version = "3.1.1.1-SNAPSHOT"
+}
+
+description = "Mybatis 增强工具包 - 只做增强不做改变，简化CRUD操作"
+
+subprojects {
+
+    apply plugin: 'java-library'
+    apply plugin: 'signing'
+    apply plugin: 'maven-publish'
+    apply plugin: 'com.github.hierynomus.license'
+
+    sourceCompatibility = "${javaVersion}"
+    targetCompatibility = "${javaVersion}"
+
+    tasks.withType(JavaCompile) {
+        options.encoding = 'UTF-8'
+        options.deprecation = true
+        options.compilerArgs += ["-parameters"]
+    }
+
+    jar {
+        afterEvaluate {
+            manifest {
+                attributes 'Implementation-Version': version
+                attributes 'Built-Gradle': gradle.gradleVersion
+                attributes 'Bundle-DocURL': 'https://mybatis.plus/'
+                attributes 'Build-OS': System.getProperty("os.name")
+                attributes 'Built-By': System.getProperty("user.name")
+                attributes 'Build-Jdk': System.getProperty("java.version")
+                attributes 'Build-Timestamp': new SimpleDateFormat("yyyy-MM-dd HH:mm:ss").format(new Date())
+            }
+        }
+    }
+    license {
+        encoding = "UTF-8"
+        header = rootProject.file("license.txt")
+        includes(["**/*.java", "**/*.kt"])
+        exclude "**/*Test.java"
+        mapping "java", "SLASHSTAR_STYLE"
+        mapping "kt", "SLASHSTAR_STYLE"
+    }
+    repositories {
+        mavenLocal()
+        maven { url "https://maven.aliyun.com/repository/public" }
+        maven { url "https://oss.sonatype.org/content/repositories/snapshots/" }
+        jcenter()
+    }
+
+    dependencies {
+        annotationProcessor "${lib.lombok}"
+        compileOnly "${lib.lombok}"
+
+        testAnnotationProcessor "${lib.lombok}"
+        testCompileOnly "${lib.lombok}"
+        testImplementation("${lib["assertj-core"]}")
+        testImplementation("${lib["junit-jupiter-api"]}")
+        testRuntimeOnly("${lib["junit-jupiter-engine"]}")
+        testCompileOnly("${lib["mockito-all"]}")
+        testImplementation("org.mockito:mockito-junit-jupiter:2.24.0")
+        testImplementation("${lib["lagarto"]}")
+    }
+
+    task sourcesJar(type: Jar) {
+        archiveClassifier.set('sources')
+        from sourceSets.main.allJava
+    }
+
+    javadoc {
+        afterEvaluate {
+            configure(options) {
+                encoding "UTF-8"
+                charSet 'UTF-8'
+                author true
+                version true
+                failOnError false
+                links "http://docs.oracle.com/javase/8/docs/api"
+            }
+        }
+    }
+
+
+    test {
+        dependsOn("cleanTest", "generatePomFileForMavenJavaPublication")
+        useJUnitPlatform()
+        exclude("**/generator/**")
+        exclude("**/postgres/**")
+        exclude("**/mysql/**")
+    }
+
+    task javadocJar(type: Jar) {
+        archiveClassifier.set('javadoc')
+        from javadoc
+    }
+
+    tasks.whenTaskAdded {
+        if (this.name.contains("signMavenJavaPublication")) {
+            this.enabled = File(project.property("signing.secretKeyRingFile") as String).isFile
+        }
+    }
+
+    publishing {
+        repositories {
+            maven {
+                def userName = System.getProperty("un")
+                def passWord = System.getProperty("ps")
+                def releasesRepoUrl = "https://oss.sonatype.org/service/local/staging/deploy/maven2/"
+                def snapshotsRepoUrl = "https://oss.sonatype.org/content/repositories/snapshots/"
+                url = version.endsWith('SNAPSHOT') ? snapshotsRepoUrl : releasesRepoUrl
+
+                credentials {
+                    username userName
+                    password passWord
+                }
+            }
+        }
+        publications {
+
+            mavenJava(MavenPublication) {
+                from components.java
+
+                artifact sourcesJar
+                artifact javadocJar
+
+                pom {
+                    name = 'mybatis-plus'
+                    packaging 'jar'
+                    description = 'An enhanced toolkit of Mybatis to simplify development.'
+                    url = 'https://github.com/baomidou/mybatis-plus'
+
+                    scm {
+                        connection = 'scm:git@github.com:Codearte/gradle-nexus-staging-plugin.git'
+                        developerConnection = 'scm:git@github.com:Codearte/gradle-nexus-staging-plugin.git'
+                        url = 'https://github.com/baomidou/mybatis-plus'
+                    }
+
+                    licenses {
+                        license {
+                            name = 'The Apache License, Version 2.0'
+                            url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
+                        }
+                    }
+
+                    developers {
+                        developer {
+                            id = 'baomidou'
+                            name = 'hubin'
+                            email = 'jobob@qq.com'
+                        }
+                    }
+
+                    withXml {
+                        def root = asNode()
+                        root.dependencies.'*'.findAll {
+                            def d = it
+                            d.scope.text() == 'runtime' && project.configurations.findByName("implementation").allDependencies.find { dep ->
+                                dep.name == it.artifactId.text()
+                            }.each() {
+                                d.scope*.value = 'compile'
+                                d.appendNode('optional', true)
+                            }
+                        }
+                    }
+                }
+            }
+        }
+
+        signing {
+            sign publishing.publications.mavenJava
+        }
+    }
+}

build.gradle.kts

@@ -1,277 +0,0 @@
-import groovy.util.Node
-import groovy.util.NodeList
-import nl.javadude.gradle.plugins.license.License
-import java.text.SimpleDateFormat
-import java.util.*
-
-buildscript {
-    repositories {
-        maven("https://plugins.gradle.org/m2/")
-    }
-
-    dependencies {
-        classpath("org.jetbrains.kotlin:kotlin-gradle-plugin:1.3.21")
-        classpath("com.netflix.nebula:gradle-extra-configurations-plugin:3.0.3")
-        classpath("gradle.plugin.com.hierynomus.gradle.plugins:license-gradle-plugin:0.15.0")
-    }
-}
-
-plugins {
-    `java-library`
-    signing
-    `maven-publish`
-}
-
-// versions
-val javaVersion = JavaVersion.VERSION_1_8
-val mybatisSpringVersion = "2.0.1"
-val mybatisVersion = "3.5.1"
-val springVersion = "5.1.6.RELEASE"
-val jsqlparserVersion = "1.2"
-val junitVersion = "5.4.0"
-val lombokVersion = "1.18.6"
-val cglibVersion = "3.2.10"
-
-// libs
-val lib = mapOf(
-    "kotlin-reflect"             to "org.jetbrains.kotlin:kotlin-reflect:1.3.21",
-    "kotlin-stdlib-jdk8"         to "org.jetbrains.kotlin:kotlin-stdlib-jdk8:1.3.21",
-    "jsqlparser"                 to "com.github.jsqlparser:jsqlparser:$jsqlparserVersion",
-    "mybatis-spring"             to "org.mybatis:mybatis-spring:$mybatisSpringVersion",
-    "mybatis"                    to "org.mybatis:mybatis:$mybatisVersion",
-    "spring-context-support"     to "org.springframework:spring-context-support:$springVersion",
-    "spring-jdbc"                to "org.springframework:spring-jdbc:$springVersion",
-    "spring-tx"                  to "org.springframework:spring-tx:$springVersion",
-    "spring-web"                 to "org.springframework:spring-web:$springVersion",
-    "spring-aop"                 to "org.springframework:spring-aop:$springVersion",
-    "cglib"                      to "cglib:cglib:$cglibVersion",
-    "lombok"                     to "org.projectlombok:lombok:$lombokVersion",
-
-    "javax.servlet-api"          to "javax.servlet:javax.servlet-api:4.0.1",
-    "aspectjweaver"              to "org.aspectj:aspectjweaver:1.9.2",
-    "mockito"                    to "org.mockito:mockito-core:2.24.0",
-    "mybatis-ehcache"            to "org.mybatis.caches:mybatis-ehcache:1.1.0",
-    "slf4j-api"                  to "org.slf4j:slf4j-api:1.7.25",
-    "logback-classic"            to "ch.qos.logback:logback-classic:1.2.3",
-    // test
-    "spring-test"                to "org.springframework:spring-test:$springVersion",
-    "assertj-core"               to "org.assertj:assertj-core:3.12.2",
-    "junit-jupiter-api"          to "org.junit.jupiter:junit-jupiter-api:$junitVersion",
-    "junit-jupiter-engine"       to "org.junit.jupiter:junit-jupiter-engine:$junitVersion",
-    "mockito-all"                to "org.mockito:mockito-all:1.10.19",
-    "fastjson"                   to "com.alibaba:fastjson:1.2.56",
-    "jackson"                    to "com.fasterxml.jackson.core:jackson-databind:2.9.6",
-    "tomcatjdbc"                 to "org.apache.tomcat:tomcat-jdbc:9.0.16",
-    // datasource
-    "p6spy"                      to "p6spy:p6spy:3.8.1",
-    "hikaricp"                   to "com.zaxxer:HikariCP:3.3.0",
-    "druid"                      to "com.alibaba:druid:1.1.13",
-    "commons-dbcp2"              to "org.apache.commons:commons-dbcp2:2.5.0",
-    "sqlserver"                  to "com.microsoft.sqlserver:sqljdbc4:4.0",
-    "postgresql"                 to "org.postgresql:postgresql:42.2.5",
-    "oracle"                     to fileTree("libs/ojdbc-11.2.0.3-jdk16.jar"),
-    "h2"                         to "com.h2database:h2:1.4.197",
-    "mysql"                      to "mysql:mysql-connector-java:8.0.15",
-    // code generator
-    "velocity"                   to "org.apache.velocity:velocity-engine-core:2.0",
-    "freemarker"                 to "org.freemarker:freemarker:2.3.28",
-    "beetl"                      to "com.ibeetl:beetl:2.9.8",
-    "lagarto"                    to "org.jodd:jodd-lagarto:5.0.7",
-    "swagger-annotations"        to "io.swagger:swagger-annotations:1.5.21"
-)
-// ext
-extra["lib"] = lib
-
-allprojects {
-    group = "com.baomidou"
-    version = "3.1.1.1-SNAPSHOT"
-}
-
-description = "Mybatis 增强工具包 - 只做增强不做改变，简化CRUD操作"
-
-subprojects {
-    // 插件
-    apply(plugin = "org.gradle.java-library")
-    apply(plugin = "org.gradle.maven-publish")
-    apply(plugin = "org.gradle.signing")
-    apply(plugin = "com.github.hierynomus.license")
-
-    // Java 版本
-    configure<JavaPluginConvention> {
-        sourceCompatibility = javaVersion
-        targetCompatibility = javaVersion
-    }
-
-    // 编译器配置
-    tasks.withType<JavaCompile> {
-        options.encoding = "UTF-8"
-        options.isDeprecation = true
-        options.compilerArgs.add("-parameters")
-    }
-
-    tasks.withType<Jar> {
-        afterEvaluate {
-            manifest {
-                attributes["Implementation-Version"] = version
-                attributes["Built-Gradle"] = gradle.gradleVersion
-                attributes["Bundle-DocURL"] = "https://mybatis.plus/"
-                attributes["Build-OS"] =  System.getProperty("os.name")
-                attributes["Built-By"] =  System.getProperty("user.name")
-                attributes["Build-Jdk"] =  System.getProperty("java.version")
-                attributes["Build-Timestamp"] =  SimpleDateFormat("yyyy-MM-dd HH:mm:ss").format(Date())
-            }
-        }
-    }
-    tasks.withType<License> {
-        encoding = "UTF-8"
-        header = rootProject.file("license.txt")
-        include("**/*.java","**/*.kt")
-        exclude ("**/*Test.java")
-        mapping("java","SLASHSTAR_STYLE")
-        mapping("kt","SLASHSTAR_STYLE")
-    }
-
-    repositories {
-        mavenLocal()
-        maven("https://maven.aliyun.com/repository/public")
-        maven("https://oss.sonatype.org/content/repositories/snapshots/")
-        jcenter()
-    }
-
-    dependencies {
-        annotationProcessor("${lib["lombok"]}")
-        compileOnly("${lib["lombok"]}")
-
-        testAnnotationProcessor("${lib["lombok"]}")
-        testCompileOnly("${lib["lombok"]}")
-        testImplementation("${lib["assertj-core"]}")
-        testImplementation("${lib["junit-jupiter-api"]}")
-        testRuntimeOnly("${lib["junit-jupiter-engine"]}")
-        testCompileOnly("${lib["mockito-all"]}")
-        testImplementation("org.mockito:mockito-junit-jupiter:2.24.0")
-        testImplementation("${lib["lagarto"]}")
-    }
-
-    val sourcesJar by tasks.registering(Jar::class) {
-        dependsOn(JavaPlugin.CLASSES_TASK_NAME)
-        archiveClassifier.set("sources")
-        from(sourceSets["main"].allJava)
-    }
-
-    tasks.withType<Javadoc> {
-        options.encoding = "UTF-8"
-        isFailOnError = false
-        (options as? StandardJavadocDocletOptions)?.also {
-            it.charSet = "UTF-8"
-            it.isAuthor = true
-            it.isVersion = true
-            it.links = listOf("https://docs.oracle.com/javase/8/docs/api")
-            if (JavaVersion.current().isJava9Compatible) {
-                it.addBooleanOption("html5", true)
-            }
-        }
-    }
-
-    tasks.withType<Test> {
-        dependsOn("cleanTest", "generatePomFileForMavenJavaPublication")
-        useJUnitPlatform()
-        exclude("**/generator/**")
-        exclude("**/postgres/**")
-        exclude("**/mysql/**")
-    }
-
-    val javadocJar by tasks.registering(Jar::class) {
-        dependsOn(JavaPlugin.JAVADOC_TASK_NAME)
-        archiveClassifier.set("javadoc")
-        from(tasks["javadoc"])
-    }
-
-    tasks.whenTaskAdded {
-        if (this.name.contains("signMavenJavaPublication")) {
-            this.enabled = File(project.property("signing.secretKeyRingFile") as String).isFile
-        }
-    }
-
-    publishing {
-        repositories {
-            maven {
-                val userName = System.getProperty("un")
-                val passWord = System.getProperty("ps")
-                val releasesRepoUrl = "https://oss.sonatype.org/service/local/staging/deploy/maven2/"
-                val snapshotsRepoUrl = "https://oss.sonatype.org/content/repositories/snapshots/"
-                setUrl(if (version.toString().endsWith("SNAPSHOT")) snapshotsRepoUrl else releasesRepoUrl)
-
-                credentials {
-                    username = userName
-                    password = passWord
-                }
-            }
-        }
-        publications {
-            register("mavenJava", MavenPublication::class) {
-                pom {
-                    name.set("mybatis-plus")
-                    description.set("An enhanced toolkit of Mybatis to simplify development.")
-                    inceptionYear.set("2016")
-                    url.set("https://github.com/baomidou/mybatis-plus")
-
-                    artifactId = project.name
-                    groupId = "${project.group}"
-                    version = "${project.version}"
-                    packaging = "jar"
-
-                    organization {
-                        name.set("baomidou")
-                    }
-
-                    scm {
-                        connection.set("scm:git@github.com:Codearte/gradle-nexus-staging-plugin.git")
-                        developerConnection.set("scm:git@github.com:Codearte/gradle-nexus-staging-plugin.git")
-                        url.set("https://github.com/baomidou/mybatis-plus")
-                    }
-
-                    licenses {
-                        license {
-                            name.set("The Apache License, Version 2.0")
-                            url.set("https://www.apache.org/licenses/LICENSE-2.0.txt")
-                        }
-                    }
-
-                    developers {
-                        developer {
-                            id.set("baomidou")
-                            name.set("hubin")
-                            email.set("jobob@qq.com")
-                        }
-                    }
-
-                    withXml {
-                        fun Any?.asNode() = this as Node
-                        fun Any?.asNodeList() = this as NodeList
-
-                        val root = asNode()
-                        root["dependencies"].asNodeList().getAt("*").forEach {
-                            val dependency = it.asNode()
-                            if (dependency["scope"].asNodeList().text() == "runtime") {
-                                if (project.configurations.findByName("implementation")?.allDependencies?.none { dep ->
-                                        dep.name == dependency["artifactId"].asNodeList().text()
-                                    } == false) {
-                                    dependency["scope"].asNodeList().forEach { it.asNode().setValue("compile") }
-                                    dependency.appendNode("optional", true)
-                                }
-                            }
-                        }
-                    }
-                }
-
-                from(components["java"])
-                artifact(sourcesJar.get())
-                artifact(javadocJar.get())
-            }
-        }
-    }
-
-    signing {
-        sign(publishing.publications.getByName("mavenJava"))
-    }
-}

mybatis-plus-boot-starter/build.gradle

@@ -0,0 +1,16 @@
+ext{
+    springBootVersion = "2.1.2.RELEASE"
+}
+dependencies {
+    api project(":mybatis-plus")
+    implementation(enforcedPlatform("org.springframework.boot:spring-boot-dependencies:${springBootVersion}" as String))
+    annotationProcessor "org.springframework.boot:spring-boot-configuration-processor:${springBootVersion}"
+    annotationProcessor "org.springframework.boot:spring-boot-autoconfigure-processor:${springBootVersion}"
+    api 'org.springframework.boot:spring-boot-autoconfigure'
+    api 'org.springframework.boot:spring-boot-starter-jdbc'
+    implementation 'org.springframework.boot:spring-boot-configuration-processor'
+    implementation 'org.springframework.boot:spring-boot-autoconfigure-processor'
+    testImplementation 'org.springframework.boot:spring-boot-starter-test'
+}
+
+compileJava.dependsOn(processResources)

mybatis-plus-boot-starter/build.gradle.kts

@@ -1,17 +0,0 @@
-val springBootVersion = "2.1.2.RELEASE"
-
-dependencies {
-    api(project(":mybatis-plus"))
-    implementation(enforcedPlatform("org.springframework.boot:spring-boot-dependencies:$springBootVersion"))
-    annotationProcessor("org.springframework.boot:spring-boot-configuration-processor:$springBootVersion")
-    annotationProcessor("org.springframework.boot:spring-boot-autoconfigure-processor:$springBootVersion")
-    api("org.springframework.boot:spring-boot-autoconfigure")
-    api("org.springframework.boot:spring-boot-starter-jdbc")
-    implementation("org.springframework.boot:spring-boot-configuration-processor")
-    implementation("org.springframework.boot:spring-boot-autoconfigure-processor")
-    testImplementation("org.springframework.boot:spring-boot-starter-test")
-}
-
-tasks.withType<JavaCompile> {
-    dependsOn(tasks.withType(ProcessResources::class))
-}

mybatis-plus-core/build.gradle

@@ -0,0 +1,20 @@
+apply plugin: 'org.jetbrains.kotlin.jvm'
+dependencies {
+    api project(":mybatis-plus-annotation")
+    api "${lib.'jsqlparser'}"
+    api "${lib.mybatis}"
+
+    implementation "${lib.cglib}"
+    implementation "${lib.'spring-aop'}"
+    
+
+    testCompile "${lib.'mybatis-ehcache'}"
+    testCompile "${lib.'logback-classic'}"
+    testCompile "${lib.'commons-dbcp2'}"
+
+    testCompile "${lib.aspectjweaver}"
+    testCompile "${lib.hikaricp}"
+    testCompile "${lib.druid}"
+    testCompile "${lib.fastjson}"
+    testCompile "${lib.tomcatjdbc}"
+}

mybatis-plus-core/build.gradle.kts

@@ -1,20 +0,0 @@
-dependencies {
-    val lib: Map<String, Any> by rootProject.extra
-
-    api(project(":mybatis-plus-annotation"))
-    api("${lib["mybatis"]}")
-    api("${lib["jsqlparser"]}")
-
-    implementation("${lib["cglib"]}")
-
-    testImplementation("${lib["mybatis-ehcache"]}")
-    testImplementation("${lib["logback-classic"]}")
-    testImplementation("${lib["commons-dbcp2"]}") {
-        exclude(module = "commons-logging")
-    }
-    testImplementation("${lib["aspectjweaver"]}")
-    testImplementation("${lib["hikaricp"]}")
-    testImplementation("${lib["druid"]}")
-    testImplementation("${lib["fastjson"]}")
-    testImplementation("${lib["tomcatjdbc"]}")
-}

mybatis-plus-extension/build.gradle.kts → mybatis-plus-extension/build.gradle

@@ -1,8 +1,4 @@
-apply(plugin = "org.jetbrains.kotlin.jvm")
-
 dependencies {
-    val lib: Map<String, Any> by rootProject.extra
-
     api(project(":mybatis-plus-core"))
     api("${lib["mybatis-spring"]}")
 

mybatis-plus-generator/build.gradle

@@ -0,0 +1,15 @@
+dependencies {
+    api project(":mybatis-plus-extension")
+
+    implementation "${lib.velocity}"
+    implementation "${lib.freemarker}"
+    implementation "${lib.beetl}"
+
+    testCompile "${lib.sqlserver}"
+    testCompile "${lib.postgresql}"
+    testCompile lib.oracle as ConfigurableFileTree
+    testCompile "${lib.h2}"
+    testCompile "${lib.mysql}"
+    testCompile "${lib.'logback-classic'}"
+    testCompile "${lib.'swagger-annotations'}"
+}

mybatis-plus-generator/build.gradle.kts

@@ -1,17 +0,0 @@
-dependencies {
-    val lib: Map<String, Any> by rootProject.extra
-
-    api(project(":mybatis-plus-extension"))
-
-    implementation("${lib["velocity"]}")
-    implementation("${lib["freemarker"]}")
-    implementation("${lib["beetl"]}")
-
-    testImplementation("${lib["sqlserver"]}")
-    testImplementation("${lib["postgresql"]}")
-    testImplementation(lib["oracle"] as ConfigurableFileTree)
-    testImplementation("${lib["h2"]}")
-    testImplementation("${lib["mysql"]}")
-    testImplementation("${lib["logback-classic"]}")
-    testImplementation("${lib["swagger-annotations"]}")
-}

mybatis-plus/build.gradle

@@ -0,0 +1,26 @@
+dependencies {
+    api project(":mybatis-plus-extension")
+    implementation project(":mybatis-plus-generator")
+
+    testCompile "${lib.'spring-web'}"
+    testCompile "${lib.'javax.servlet-api'}"
+
+    testCompile "${lib.'spring-test'}"
+    testCompile "${lib.fastjson}"
+
+    testCompile "${lib.hikaricp}"
+    testCompile "${lib.'commons-dbcp2'}"
+    testCompile "${lib.druid}"
+    testCompile "${lib.tomcatjdbc}"
+
+    testCompile "${lib.h2}"
+    testCompile "${lib.sqlserver}"
+    testCompile "${lib.postgresql}"
+    testCompile lib.oracle as ConfigurableFileTree
+    testCompile "${lib.mysql}"
+    testCompile "${lib.jackson}"
+    testCompile "${lib.'logback-classic'}"
+
+    testCompile "${lib.'spring-context-support'}"
+    testCompile "${lib.'spring-jdbc'}"
+}

mybatis-plus/build.gradle.kts

@@ -1,28 +0,0 @@
-dependencies {
-    val lib: Map<String, Any> by rootProject.extra
-
-    api(project(":mybatis-plus-extension"))
-    implementation(project(":mybatis-plus-generator"))
-
-    testImplementation("${lib["spring-web"]}")
-    testImplementation("${lib["javax.servlet-api"]}")
-
-    testImplementation("${lib["spring-test"]}")
-    testImplementation("${lib["fastjson"]}")
-
-    testImplementation("${lib["hikaricp"]}")
-    testImplementation("${lib["commons-dbcp2"]}")
-    testImplementation("${lib["druid"]}")
-    testImplementation("${lib["tomcatjdbc"]}")
-
-    testImplementation("${lib["h2"]}")
-    testImplementation("${lib["sqlserver"]}")
-    testImplementation("${lib["postgresql"]}")
-    testImplementation(lib["oracle"] as ConfigurableFileTree)
-    testImplementation("${lib["mysql"]}")
-    testImplementation("${lib["jackson"]}")
-    testImplementation("${lib["logback-classic"]}")
-
-    testImplementation("${lib["spring-context-support"]}")
-    testImplementation("${lib["spring-jdbc"]}")
-}

settings.gradle

@@ -0,0 +1,7 @@
+rootProject.name = 'mybatis-plus-root'
+include 'mybatis-plus'
+include 'mybatis-plus-core'
+include 'mybatis-plus-annotation'
+include 'mybatis-plus-extension'
+include 'mybatis-plus-generator'
+include 'mybatis-plus-boot-starter'

settings.gradle.kts

@@ -1,8 +0,0 @@
-rootProject.name = "mybatis-plus-root"
-
-include(":mybatis-plus")
-include(":mybatis-plus-core")
-include(":mybatis-plus-annotation")
-include(":mybatis-plus-extension")
-include(":mybatis-plus-generator")
-include(":mybatis-plus-boot-starter")